寻观「标准库」之「数据结构」之「多态列」之书。
寻观「标准库」之「数据结构」之「多态列工具」之书。

寻观「标准库」之「语言核心」之「内建类型」之书。
寻观「标准库」之「语言核心」之「续延」之书。
寻观「标准库」之「语言核心」之「异常」之书。

「： 注 string list。 ：」

寻观「标准库」之「数据结构」之「整数操作」之书。

寻观「标准库」之「数据结构」之「可选值」之书。


寻观「标准库」之「数学运算」之「数组转换」之书。


「串转通字符」乃化「字符串」而「列」于「字符串」也。
「串转通字符」者会「串」而（「数组转多态列」授以「字符串」）于（《《C调用》》名『豫言_获取通字符』传「串」）也。

「获取字符」者「串转通字符」也。

「通字符转串」乃化（「列」于「字符串」）而「字符串」也。
「通字符转串」者会「列」而
    虑「后列」者（（「多态列转数组」授以「字符串」）于「列」）而
    《《C调用》》名『豫言_通字符拼接』传「后列」也。

「合并」者「通字符转串」也。
「串组合并」者「通字符转串」也。


「字符串拼接」乃化「字符串」而化「字符串」而「字符串」也。
「字符串拼接」者会「串甲」而会「串乙」而《《C调用》》名『豫言_字符串拼接』传「串甲」与「串乙」也。

「间合」乃化「字符串」而化（「列」于「字符串」）而「字符串」也。
「间合」者会「分隔符」而会「字符串列」而
    递归虑「处理」其化（「列」于「字符串」）而（「列」于「字符串」）者
        会「剩余」而
            鉴「剩余」而
                有「罄」则「罄」
                或有（「列」【「甲」】）则（「列」【「甲」】）
                或有「缀」于「甲」于「乙」则「缀」于「甲」于（「缀」于「分隔符」于（「处理」于「乙」））
    而
        虑「结果」者「处理」于「字符串列」而
        「串组合并」于「结果」
    也。

「字符串相等吗」乃化「字符串」而化「字符串」而「爻」也。
「字符串相等吗」者会「串甲」而会「串乙」而《《C调用》》名『豫言_字符串相等』传「串甲」与「串乙」也。


「串相等」者「字符串相等吗」也。
「字符串相等」者「字符串相等吗」也。

「串组相等」乃化（「列」于「字符串」）而化（「列」于「字符串」）而「爻」也。
「串组相等」者会「甲」而会「乙」而
    鉴「甲」与「乙」而
        有「罄」与「罄」则「阳」
        或有（「缀」于「甲头」于「甲尾」）与（「缀」于「乙头」于「乙尾」）则（若「串相等」于「甲头」于「乙头」则「串组相等」于「甲尾」于「乙尾」否则「阴」）
        或有「其他」则「阴」也。


「是子字符串吗」乃化「字符串」而化「字符串」而「爻」也。
「是子字符串吗」者会「串甲」而会「串乙」而《《C调用》》名『豫言_是子字符串』传「串甲」与「串乙」也。

「： 注：串结尾是它吗 1 2 测试1是否为2的结尾。 ：」
「串结尾是它吗」乃化「字符串」而化「字符串」而「爻」也。
「串结尾是它吗」者会「串一」而会「串二」而
    （（「多态列」之「以终否」）授以「字符串」）
        于（「字符串相等吗」）
        于（「串转通字符」于（「串一」））
        于（「串转通字符」于（「串二」））也。

「串开头是它吗」乃化「字符串」而化「字符串」而「爻」也。
「串开头是它吗」者会「串一」而会「串二」而
    （（「多态列」之「以起否」）授以「字符串」）
        于（「字符串相等吗」）
        于（「串转通字符」于（「串一」））
        于（「串转通字符」于（「串二」））也。

「：从第二个参数结尾删除长度为第一个长度的字符串：」
「去除串结尾」乃化「字符串」而化「字符串」而「字符串」也。
「去除串结尾」者会「串一」而会「串二」而
    「通字符转串」于
        （（（「多态列」之「结尾放」）授以「字符串」）
        于（（（「多态列」之「长度」）授以「字符串」）于（「串转通字符」于（「串一」）））
        于（「串转通字符」于（「串二」）））也。

「：从第二个参数开头删除长度为第一个长度的字符串：」
「去除串开头」乃化「字符串」而化「字符串」而「字符串」也。
「去除串开头」者会「串一」而会「串二」而
    「通字符转串」于
        （（（「多态列」之「放」）授以「字符串」）
        于（（（「多态列」之「长度」）授以「字符串」）于（「串转通字符」于（「串一」）））
        于（「串转通字符」于（「串二」）））也。

「表示串」乃化「字符串」而「字符串」也。
「表示串」者会「串」而「串组合并」于（「列」【『『』，（递归虑「处理」其化（「列」于「字符串」）而（「列」于「字符串」）者
        会「列」而
            鉴「列」而
            有「缀」于『「：换行：」』于「尾」则「缀」于『「：「：：」换行：」』于（「处理」于「尾」）
            或有「缀」于『「：制表：」』于「尾」则「缀」于『「：「：：」制表：」』于（「处理」于「尾」）
            或有「缀」于『「：』：」』于「尾」则「缀」于『「：「：：」「：』：」：」』于（「处理」于「尾」）
            或有「缀」于『「』于（「缀」于『：』于「尾」）则「缀」于『「：「：：」「：「：：」：」』于（「处理」于「尾」）
            或有「缀」于「其他」于「尾」则「缀」于「其他」于（「处理」于「尾」）
            或有「罄」则「罄」
    而
        虑「结果」者「串组合并」于（「处理」于（「获取字符」于「串」））而
        「结果」
    ），『「：』：」』】）也。

「获取子字符串」乃化「整数」而化「整数」而化「字符串」而「字符串」也。
「获取子字符串」者会「始」而会「止」而会「串」而
    「串组合并」于（（「取」授以「字符串」）于（「减」于「止」于「始」）于（（「放」授以「字符串」）于「始」于（「获取字符」于「串」）））也。

「串长度」乃化「字符串」而「整数」也。
「串长度」者会「串」而（（「长度」授以「字符串」）于（「获取字符」于「串」））也。

「：第一个爻为从左或从右：」
「搜索单个」乃化「爻」而化「字符串」而化「字符串」而（「或可有」于「整数」）也。
「搜索单个」者会「从左」而会「搜索」而会「串」而
虑「字符们」者「获取字符」于「串」而
    （「以当前续延调用」于（
        会「返回」而
            （（「列」于「有」也（「态射」授以「整数」授以「有」）于（（化（「列」于「整数」）而（「列」于「整数」）也若「从左」则（会「甲」而「甲」）否则（会「整数列」而「反转」授以「整数」于「整数列」））
                    于（「整数范围」于「零」于（（「长度」授以「字符串」）于「字符们」））
                ）于（会「当前数值」而
                    若（「以起否」授以「字符串」）于「串相等」于（「获取字符」于「搜索」）于（（「放」授以「字符串」）于「当前数值」于「字符们」）
                    则（「返回」于（「可有」于「当前数值」））
                    否则「元」
                ））；
                「可无」
            ）
    ））也。

「串从左搜索单个」乃化「字符串」而化「字符串」而（「或可有」于「整数」）也。
「串从左搜索单个」者会「搜索」而会「串」而「搜索单个」于「阳」于「搜索」于「串」也。
「串从右搜索单个」乃化「字符串」而化「字符串」而（「或可有」于「整数」）也。
「串从右搜索单个」者会「搜索」而会「串」而「搜索单个」于「阴」于「搜索」于「串」也。

「字节长度」乃化「字符串」而「整数」也。
「字节长度」者会「串」而《《C调用》》名『豫言_字符串字节长度』传「串」也。

「：字符转整数于串于序数

将返回串的第序数个byte的整数值，使用C字符串的表示方式。
序数必须小于等于字节长度，如果序数等于字节长度，将返回零：」
「字符转整数」乃化「字符串」而化「整数」而「整数」也。
「字符转整数」者会「串」而会「序数」而
    若（「大于」于「序数」于（「字节长度」于「串」））则「发生事故」于『序数超出范围』
    否则（《《C调用》》名『豫言_字符转整数』传「串」与「序数」）也。

「字节转字符串」乃化「整数」而「字符串」也。
「字节转字符串」者会「字节」而《《C调用》》名『豫言_字节转字符串』传「字节」也。

「字符串转无调拼音」乃化「字符串」而「字符串」也。
「字符串转无调拼音」者会「文本」而
    《《C调用》》名『豫言_字符串转无调拼音』传「文本」也。

「字符串转拼音首字母」乃化「字符串」而「字符串」也。
「字符串转拼音首字母」者会「文本」而
    《《C调用》》名『豫言_字符串转拼音首字母』传「文本」也。

「串是模糊子序列吗」乃化「字符串」而化「字符串」而「爻」也。
「串是模糊子序列吗」者会「查询」而会「目标」而
    递归虑「继续比较」其化（「列」于「字符串」）而化（「列」于「字符串」）而「爻」者
        会「查询字符」而会「目标字符」而
        鉴「查询字符」而
            有「罄」则「阳」
            或有（「缀」于「查询首字」于「查询其余」）则
                鉴「目标字符」而
                    有「罄」则「阴」
                    或有（「缀」于「目标首字」于「目标其余」）则
                        若「字符串相等吗」于「查询首字」于「目标首字」
                        则「继续比较」于「查询其余」于「目标其余」
                        否则「继续比较」于「查询字符」于「目标其余」
    而「继续比较」于（「获取字符」于「查询」）于（「获取字符」于「目标」）
也。

「串含非阿斯基字符吗」乃化「字符串」而「爻」也。
「串含非阿斯基字符吗」者会「文本」而
    （「存在吗」授以「字符串」）于
        （会「字符」而「大于」于（「字符转整数」于「字符」于「零」）于「一二七」）于
        （「获取字符」于「文本」）
也。


「串查找替换」乃化「字符串」「：目标字符串：」
          而化「字符串」「：寻找字符串：」
          而化「字符串」「：替换字符串：」
          而「字符串」也。
「串查找替换」者会「原先」而会「寻找」而会「替换」而
    「串组合并」于（（「列查找替换」授以「字符串」）
                于「串相等」
                于（「获取字符」于「原先」）
                于（「获取字符」于「寻找」）
                于（「获取字符」于「替换」））也。



「多态列表示」乃承「甲」而化（化「甲」而「字符串」）而化（「列」于「甲」）而「字符串」也。
「多态列表示」者受「甲」而会「元素表示」而会「列」而
    「串组合并」于（（「列」【『【』，（「间合」于『，』于（（「态射」）于「列」于「元素表示」）），『】』】））也。

「串列表示」乃化（「列」于「字符串」）而「字符串」也。
「串列表示」者会「列」而
    （「多态列表示」授以「字符串」）于（会「甲」而「甲」）于「列」也。

「可选值表示」乃承「甲」而化（化「甲」而「字符串」）而化（「或可有」于「甲」）而「字符串」也。
「可选值表示」者受「甲」而会「元素表示」而会「可选」而
    鉴「可选」而
        有「可无」则『可无』
        或有（「可有」于「元素」）则
            「串组合并」于（（「列」【『可有（』，（「元素表示」于「元素」），『）』】））
    也。
