寻观「标准库」之书。
寻观「编译器核心」之「网页汇编核心」之「模块结构」之书。
寻观「编译器核心」之「编译步骤」之「代码生成」之「底层后端」之「底层中间式」之书。
寻观「编译器核心」之「编译步骤」之「代码生成」之「底层后端」之「底层读取」之书。

「：文言：生成：简树转 Wasm 指令。凡式皆留一三十二位整数于栈（单元为零）；局部变量按作用域分配；内联循环与分派用结构化控制。汉语：把提升、化简之后的简树生成 `网页指令` 列表。值约定：每个式恰好在操作数栈上留下一个 i32（单元值为 0；写内存等无结果的原语在操作后补一个 0）。局部下标：形参在前，其后按作用域顺序分配，同级分支复用下标；总数由指令扫描得出。`深` 是当前打开的控制结构数，用于计算 `br` 的相对深度。：」

「：文言：二元运算之指令，未知则无。汉语：外部调用名对应的二元 Wasm 指令。：」
「低层二元指令」乃化「字符串」而（「或可有」于「网页指令」）也。
「低层二元指令」者会「名」而
  若「串相等」于「名」于『底层_加』则
    「可有」于「网页加」
  否则若「串相等」于「名」于『底层_减』则「可有」于「网页减」
  否则若「串相等」于「名」于『底层_乘』则「可有」于「网页乘」
  否则若「串相等」于「名」于『底层_有符号除』则「可有」于「网页有符号除」
  否则若「串相等」于「名」于『底层_无符号除』则「可有」于「网页无符号除」
  否则若「串相等」于「名」于『底层_有符号余』则「可有」于「网页有符号余」
  否则若「串相等」于「名」于『底层_无符号余』则「可有」于「网页无符号余」
  否则若「串相等」于「名」于『底层_位与』则「可有」于「网页按位与」
  否则若「串相等」于「名」于『底层_位或』则「可有」于「网页按位或」
  否则若「串相等」于「名」于『底层_位异或』则「可有」于「网页按位异或」
  否则若「串相等」于「名」于『底层_左移』则「可有」于「网页左移」
  否则若「串相等」于「名」于『底层_有符号右移』则「可有」于「网页有符号右移」
  否则若「串相等」于「名」于『底层_无符号右移』则「可有」于「网页无符号右移」
  否则若「串相等」于「名」于『底层_循环左移』则「可有」于「网页循环左移」
  否则若「串相等」于「名」于『底层_循环右移』则「可有」于「网页循环右移」
  否则若「串相等」于「名」于『底层_等』则「可有」于「网页相等」
  否则若「串相等」于「名」于『底层_不等』则「可有」于「网页不等」
  否则若「串相等」于「名」于『底层_有符号小于』则「可有」于「网页有符号小于」
  否则若「串相等」于「名」于『底层_有符号大于』则「可有」于「网页有符号大于」
  否则若「串相等」于「名」于『底层_有符号小等』则「可有」于「网页有符号小等」
  否则若「串相等」于「名」于『底层_有符号大等』则「可有」于「网页有符号大等」
  否则若「串相等」于「名」于『底层_无符号小于』则「可有」于「网页无符号小于」
  否则若「串相等」于「名」于『底层_无符号大于』则「可有」于「网页无符号大于」
  否则若「串相等」于「名」于『底层_无符号小等』则「可有」于「网页无符号小等」
  否则若「串相等」于「名」于『底层_无符号大等』则「可有」于「网页无符号大等」
  否则
    「可无」
也。

「低层读指令」乃化「字符串」而（「或可有」于「网页指令」）也。
「低层读指令」者会「名」而
  若「串相等」于「名」于『底层_读四』则
    「可有」于（「网页内存读四」于「二」于「零」）
  否则若「串相等」于「名」于『底层_读二』则「可有」于（「网页内存读十六无符号」于「一」于「零」）
  否则若「串相等」于「名」于『底层_读二有符号』则「可有」于（「网页内存读十六有符号」于「一」于「零」）
  否则若「串相等」于「名」于『底层_读一』则「可有」于（「网页内存读八无符号」于「零」于「零」）
  否则若「串相等」于「名」于『底层_读一有符号』则「可有」于（「网页内存读八有符号」于「零」于「零」）
  否则
    「可无」
也。

「低层写指令」乃化「字符串」而（「或可有」于「网页指令」）也。
「低层写指令」者会「名」而
  若「串相等」于「名」于『底层_写四』则
    「可有」于（「网页内存写四」于「二」于「零」）
  否则若「串相等」于「名」于『底层_写二』则「可有」于（「网页内存写十六」于「一」于「零」）
  否则若「串相等」于「名」于『底层_写一』则「可有」于（「网页内存写八」于「零」于「零」）
  否则
    「可无」
也。

「按段拆」乃化「字符串」而化「字符串」而（「列」于「字符串」）也。
「按段拆」者会「分隔」而会「文」而
  「态射」授以（「列」于「字符串」）授以「字符串」
    于（「元素分隔」授以「字符串」于（会「字」而「串相等」于「字」于「分隔」）于（「获取字符」于「文」））
    于「串组合并」
也。

「低层解自然数」乃化「字符串」而（「或可有」于「整数」）也。
「低层解自然数」者会「文」而
  若「串相等」于「文」于『』则
    「可无」
  否则若「全部符合」授以「字符串」
    于（会「字」而「是子字符串吗」于「字」于『0123456789』）
    于（「获取字符」于「文」）则「可有」
      于（「理解整数」于「文」）
  否则
    「可无」
也。

「：文言：导入之名：导入：模块：字段：参数数：结果数。汉语：解析外部调用名中的导入声明；不是导入名则无。返回（模块、字段、参数数、结果数）。：」
「低层解导入名」乃
  化「字符串」而
  （「或可有」于（「字符串」合「字符串」合「整数」合「整数」））
也。
「低层解导入名」者会「名」而
  若「串开头是它吗」于『导入：』于「名」则（
    鉴「按段拆」于『：』于「名」而
      有（「列」【「前缀」，「模块」，「字段」，「参数」，「结果」】）则（
        鉴「低层解自然数」于「参数」而
          有「可有」于「参数数」则（
            鉴「低层解自然数」于「结果」而
              有「可有」于「结果数」则
                「可有」于（「模块」与「字段」与「参数数」与「结果数」）
              或有「可无」则「可无」
          ）
          或有「可无」则「可无」
      ）
      或有「其他」则「可无」
  ）
  否则
    「可无」
也。

「生成上下文」立「元类型」也。
  「构造生成上下文」立化（「列」于（「字符串」合「整数」））而化（「列」
  于（「字符串」合「整数」合（「列」于「整数」）））而化（「列」于（「字符串」合「整数」））而「生成上下文」也。 「：局部表（名、下标）、环表（标、打开时的深度、形参下标们）、函数号表（全局名或导入名、函数下标）：」
  「低层查串整」乃
    化（「列」于（「字符串」合「整数」））而
    化「字符串」而
    （「或可有」于「整数」）
也。
「低层查串整」者会「表」而会「键」而
  鉴「表」而
    有「罄」则「可无」
    或有「缀」于「首」于「尾」则
      若「串相等」于（「首」中「零」）于「键」则「可有」于（「首」中「一」）否则「低层查串整」于「尾」于「键」
也。

「低层查环表」乃
  化（「列」于（「字符串」合「整数」合（「列」于「整数」）））而
  化「字符串」而
  （「或可有」于（「整数」合（「列」于「整数」）））
也。
「低层查环表」者会「表」而会「键」而
  鉴「表」而
    有「罄」则「可无」
    或有「缀」于「首」于「尾」则
      若「串相等」于（「首」中「零」）于「键」则
        「可有」于（（「首」中「一」）与（「首」中「二」））
      否则
        「低层查环表」于「尾」于「键」
也。

「低层局部下标」乃化「生成上下文」而化「字符串」而「整数」也。
「低层局部下标」者会「上下」而会「名」而
  鉴「上下」而
    有「构造生成上下文」于「局表」于「环表」于「函表」则（
      鉴「低层查串整」于「局表」于「名」而
        有「可有」于「号」则「号」
        或有「可无」则
          「低层出错」授以「整数」于（『局部变量未分配下标：』附「名」）
    ）
也。

「低层加局部」乃化「生成上下文」而化「字符串」而化「整数」而「生成上下文」也。
「低层加局部」者会「上下」而会「名」而会「号」而
  鉴「上下」而
    有「构造生成上下文」于「局表」于「环表」于「函表」则
      「构造生成上下文」于（「缀」于（「名」与「号」）于「局表」）于「环表」于「函表」
也。

「低层加环」乃
  化「生成上下文」而
  化「字符串」而
  化「整数」而
  化（「列」于「整数」）而
  「生成上下文」
也。
「低层加环」者会「上下」而会「标」而会「深」而会「局们」而
  鉴「上下」而
    有「构造生成上下文」于「局表」于「环表」于「函表」则
      「构造生成上下文」于「局表」于（「缀」于（「标」与「深」与「局们」）于「环表」）于「函表」
也。

「低层函数下标」乃化「生成上下文」而化「字符串」而「整数」也。
「低层函数下标」者会「上下」而会「名」而
  鉴「上下」而
    有「构造生成上下文」于「局表」于「环表」于「函表」则（
      鉴「低层查串整」于「函表」于「名」而
        有「可有」于「号」则「号」
        或有「可无」则
          「低层出错」授以「整数」于（『调用了未定义或不可达的函数：』附「名」）
    ）
也。

「：文言：串联多列指令。汉语：把若干指令列表按序拼接。：」
「低层拼令」乃
  化（「列」于（「列」于「网页指令」））而
  （「列」于「网页指令」）
也。
「低层拼令」者会「们」而
  「串联」授以「网页指令」于「们」
也。

「低层单令」乃化「网页指令」而（「列」于「网页指令」）也。
「低层单令」者会「令」而
  「列」【「令」】
也。

「：文言：一遍插序，键小者先。汉语：把（键、序）对按键升序插入；同键是编译错误（分派前已去重）。：」
「低层插序」乃
  化（「整数」合「整数」）而
  化（「列」于（「整数」合「整数」））而
  （「列」于（「整数」合「整数」））
也。
「低层插序」者会「项」而会「们」而
  鉴「们」而
    有「罄」则「缀」于「项」于（「罄」授以（「整数」合「整数」））
    或有「缀」于「首」于「尾」则
      若「小于」于（「项」中「零」）于（「首」中「零」）则
        「缀」于「项」于「们」
      否则
        「缀」于「首」于（「低层插序」于「项」于「尾」）
也。

「低层排序」乃
  化（「列」于（「整数」合「整数」））而
  （「列」于（「整数」合「整数」））
也。
「低层排序」者会「们」而
  「从左折叠」授以（「整数」合「整数」）授以（「列」于（「整数」合「整数」））
  于（会「项」而会「累」而「低层插序」于「项」于「累」）
  于（「罄」授以（「整数」合「整数」））
  于「们」
也。

「低层取前对」乃
  化「整数」而
  化（「列」于（「整数」合「整数」））而
  （「列」于（「整数」合「整数」））
也。
「低层取前对」者会「数」而会「们」而
  若「小于」于「数」于「一」则
    「罄」授以（「整数」合「整数」）
  否则
    鉴「们」而
      有「罄」则「罄」授以（「整数」合「整数」）
      或有「缀」于「首」于「尾」则
        「缀」于「首」于（「低层取前对」于（「减」于「数」于「一」）于「尾」）
也。

「低层去前对」乃
  化「整数」而
  化（「列」于（「整数」合「整数」））而
  （「列」于（「整数」合「整数」））
也。
「低层去前对」者会「数」而会「们」而
  若「小于」于「数」于「一」则「们」
  否则
    鉴「们」而
      有「罄」则「罄」授以（「整数」合「整数」）
      或有「缀」于「首」于「尾」则
        「低层去前对」于（「减」于「数」于「一」）于「尾」
也。

「：文言：决策之树：少者线性而比，多者折半而分。汉语：在 `br` 目标为“第 序 号块”的约定下，生成对已排序（键、序）的判断：至多四项时逐项 `br_if`，最后无条件 `br` 到缺省；更多时以枢轴 `<` 分成 `if/else`，内嵌一层，故目标下标加一。：」
「低层决策树」乃
  化「整数」而
  化（「列」于（「整数」合「整数」））而
  化「整数」而
  化「整数」而
  （「列」于「网页指令」）
也。
「低层决策树」者会「暂」而会「对们」而会「缺省序」而会「嵌」而
  若「非」于（「大于」于（「长度」授以（「整数」合「整数」）于「对们」）于「四」）则
    「串联」授以「网页指令」于（「列」【
      「串联」授以「网页指令」于（「态射」授以（「整数」合「整数」）授以（「列」于「网页指令」）
      于「对们」
      于（会「对」而「列」【
        「网页局部读取」于「暂」，
        「网页常量」于（「对」中「零」），
        「网页相等」，
        「网页条件跳转」于（「加」于（「对」中「一」）于「嵌」）
      】
      ）），
      「列」【「网页跳转」于（「加」于「缺省序」于「嵌」）】
    】）
  否则
    虑「半」者
      「除以」于（「长度」授以（「整数」合「整数」）于「对们」）于「二」
    而
    虑「枢」者
      （「第N个」授以（「整数」合「整数」）于「半」于「对们」）中「零」
    而
    「串联」授以「网页指令」于（「列」【
      「列」【
        「网页局部读取」于「暂」，
        「网页常量」于「枢」，
        「网页有符号小于」，
        「网页条件」于「零」
      】，
      「低层决策树」于「暂」于（「低层取前对」于「半」于「对们」）于「缺省序」
      于（「加」于「嵌」于「一」），
      「列」【「网页否则」】，
      「低层决策树」于「暂」于（「低层去前对」于「半」于「对们」）于「缺省序」
      于（「加」于「嵌」于「一」），
      「列」【「网页结束」】
    】）
也。

「低层局部表」乃化「生成上下文」而（「列」于（「字符串」合「整数」））也。
「低层局部表」者会「上下」而
  鉴「上下」而
    有「构造生成上下文」于「局表」于「环表」于「函表」则「局表」
也。

「低层环表」乃
  化「生成上下文」而
  （「列」于（「字符串」合「整数」合（「列」于「整数」）））
也。
「低层环表」者会「上下」而
  鉴「上下」而
    有「构造生成上下文」于「局表」于「环表」于「函表」则「环表」
也。

「环分配结果」立「元类型」也。
  「构造环分配结果」立化「生成上下文」而化「整数」而化（「列」于「整数」）而化（「列」于（「整数」合「低层项」））而
  「环分配结果」也。 「：新上下文、新的下一个局部下标、各形参下标、须赋初值者（下标、初值）：」
「：文言：环之形参，若初值即形参自身且已有下标，则沿用，不复赋值；否则新立局部。汉语：为内联循环的形参分配局部下标。函数级循环的形参就是函数形参，初值是自身，故全部沿用。：」
「低层环分配」乃
  化「生成上下文」而
  化「整数」而
  化（「列」于「字符串」）而
  化（「列」于「低层项」）而
  化（「列」于「整数」）而
  化（「列」于（「整数」合「低层项」））而
  「环分配结果」
也。
「低层环分配」者会「上下」而会「下个」而会「形们」而会「初们」而会「局累」而会「赋累」而
  鉴「形们」而
    有「罄」则「构造环分配结果」
      于「上下」
      于「下个」
      于（「反转」授以「整数」于「局累」）
      于（「反转」授以（「整数」合「低层项」）于「赋累」）
    或有「缀」于「形」于「余形」则（
      鉴「初们」而
        有「缀」于「初」于「余初」则（
          虑「原下标」者（「或可有」于「整数」）也（
            鉴「初」而
              有「项局」于「他」则
                （若「串相等」于「他」于「形」则「低层查串整」于（「低层局部表」于「上下」）于「形」否则「可无」）
              或有「余项」则「可无」
          ）而
          鉴「原下标」而
            有「可有」于「号」则
              「低层环分配」
                于「上下」
                于「下个」
                于「余形」
                于「余初」
                于（「缀」于「号」于「局累」）于「赋累」
            或有「可无」则
              「低层环分配」
                于（「低层加局部」于「上下」于「形」于「下个」）
                于（「加」于「下个」于「一」）
                于「余形」
                于「余初」
                于（「缀」于「下个」于「局累」）
                于（「缀」于（「下个」与「初」）于「赋累」）
        ）
        或有「罄」则「低层出错」授以「环分配结果」
        于『内部错误：环的初值个数与形参个数不符』
    ）
也。

「：文言：外部调用之生成：运算、读写、内存、陷阱、选择、格、导入。导入之参数数为零者，调用处依豫言之例传单元 无，生成时弃之。汉语：`生成` 是把子项生成指令的函数（由 `低层生成` 传入自身，以便互递归）。声明为零个参数的导入，调用处按豫言的写法传一个单元 `无`，生成指令时丢弃这个实参。：」
「低层生成外」乃
  化（化「低层项」而（「列」于「网页指令」））而
  化「生成上下文」而
  化「字符串」而
  化（「列」于「低层项」）而
  （「列」于「网页指令」）
也。
「低层生成外」者会「生成」而会「上下」而会「名」而会「参们」而
  虑「全」者（化（「列」于「低层项」）而（「列」于「网页指令」））也（会「们」而
  「串联」授以「网页指令」于（「态射」授以「低层项」授以（「列」于「网页指令」）于「们」于「生成」））而
  虑「错个数」者（化「有」而（「列」于「网页指令」））也（会「无」而
  「低层出错」授以（「列」于「网页指令」）
  于（『外部调用〈』附「名」附『〉的实参个数不符』））而
  鉴「低层二元指令」于「名」而
    有「可有」于「指」则（
      鉴「参们」而
        有（「列」【「甲」，「乙」】）则
          「串联」授以「网页指令」于（「列」【「生成」于「甲」，「生成」于「乙」，「列」【「指」】】）
        或有「其余」则「错个数」于「元」
    ）
    或有「可无」则（
      鉴「低层读指令」于「名」而
        有「可有」于「读」则（
          鉴「参们」而
            有（「列」【「址」】）则
              「串联」授以「网页指令」于（「列」【「生成」于「址」，「列」【「读」】】）
            或有「其余」则「错个数」于「元」
        ）
        或有「可无」则（
          鉴「低层写指令」于「名」而
            有「可有」于「存」则（
              鉴「参们」而
                有（「列」【「址」，「值」】）则
                  「串联」授以「网页指令」
                  于（「列」【「生成」于「址」，「生成」于「值」，「列」【「存」，「网页常量」于「零」】】）
                或有「其余」则「错个数」于「元」
            ）
            或有「可无」则（
              若「串相等」于「名」于『底层_为零』则（
                鉴「参们」而
                  有（「列」【「甲」】）则
                    「串联」授以「网页指令」
                    于（「列」【「生成」于「甲」，「列」【「网页为零」】】）
                  或有「其余」则「错个数」于「元」
              ）
              否则若「串相等」于「名」于『底层_内存页数』则「列」【「网页内存大小」于「零」】
              否则若「串相等」于「名」于『底层_内存增长』则（
                鉴「参们」而
                  有（「列」【「甲」】）则
                    「串联」授以「网页指令」
                    于（「列」【「生成」于「甲」，「列」【「网页内存增长」于「零」】】）
                  或有「其余」则「错个数」于「元」
              ）
              否则若「串相等」于「名」于『底层_内存复制』则（
                鉴「参们」而
                  有（「列」【「目」，「源」，「长」】）则
                    「串联」授以「网页指令」
                    于（「列」【
                      「生成」于「目」，
                      「生成」于「源」，
                      「生成」于「长」，
                      「列」【「网页内存复制令」于「零」于「零」，「网页常量」于「零」】
                    】）
                  或有「其余」则「错个数」于「元」
              ）
              否则若「串相等」于「名」于『底层_内存填充』则（
                鉴「参们」而
                  有（「列」【「目」，「字节」，「长」】）则
                    「串联」授以「网页指令」
                    于（「列」【
                      「生成」于「目」，
                      「生成」于「字节」，
                      「生成」于「长」，
                      「列」【「网页内存填充令」于「零」，「网页常量」于「零」】
                    】）
                  或有「其余」则「错个数」于「元」
              ）
              否则若「串相等」于「名」于『底层_陷阱』则「列」【「网页陷阱」】
              否则若「串相等」于「名」于『底层_选择』则（
                鉴「参们」而
                  有（「列」【「条」，「甲」，「乙」】）则
                    「串联」授以「网页指令」
                    于（「列」【「生成」于「甲」，「生成」于「乙」，「生成」于「条」，「列」【「网页选择」】】）
                  或有「其余」则「错个数」于「元」
              ）
              否则若「串相等」于「名」于『底层_读格』则（
                鉴「参们」而
                  有（「列」【（「项局」于「格」）】）则
                    「列」【「网页局部读取」于（「低层局部下标」于「上下」于「格」）】
                  或有「其余」则
                    「低层出错」授以（「列」于「网页指令」）
                    于『读格的实参必须是格变量本身』
              ）
              否则若「串相等」于「名」于『底层_写格』则（
                鉴「参们」而
                  有（「列」【（「项局」于「格」），「值」】）则
                    「串联」授以「网页指令」
                    于（「列」【
                      「生成」于「值」，
                      「列」【「网页局部写入」于（「低层局部下标」于「上下」于「格」），「网页常量」于「零」】
                    】）
                  或有「其余」则
                    「低层出错」授以（「列」于「网页指令」）
                    于『写格的首个实参必须是格变量本身』
              ）
              否则若「串相等」于「名」于『底层_新格』则
                「低层出错」授以（「列」于「网页指令」）
                于『新格只能直接绑定给变量（虑 变量 者 新格 …）』
              否则
                （
                  鉴「低层解导入名」于「名」而
                    有「可有」于「解」则（
                      虑「实参们」者（「列」于「低层项」）也（
                        若「等于」于（「解」中「二」）于「零」则
                          「罄」授以「低层项」
                        否则
                          「参们」
                      ）
                      而
                      若「不等于」
                        于（「长度」授以「低层项」于「实参们」）
                        于（「解」中「二」）则
                          「错个数」于「元」
                      否则
                        「串联」授以「网页指令」
                        于（「列」【
                          「全」于「实参们」，
                          「列」【「网页调用」于（「低层函数下标」于「上下」于「名」）】，
                          若「等于」于（「解」中「三」）于「零」则
                            「列」【「网页常量」于「零」】
                          否则
                              「罄」授以「网页指令」
                        】）
                    ）
                    或有「可无」则
                      「低层出错」授以（「列」于「网页指令」）
                      于（『未知的外部调用：』附「名」）
                ）
            ）
        ）
    ）
也。

「：文言：生成一式，栈上留一整数。汉语：`低层生成 上下 下个 深 项`：`下个` 是下一个可用局部下标，`深` 是当前控制结构层数。：」
「低层生成」乃
  化「生成上下文」而
  化「整数」而
  化「整数」而
  化「低层项」而
  （「列」于「网页指令」）
也。
「低层生成」者会「上下」而会「下个」而会「深」而会「项」而
  虑「生成们」者（化（「列」于「低层项」）而（「列」于「网页指令」））也（会「们」而
  「串联」授以「网页指令」于（「态射」授以「低层项」授以（「列」于「网页指令」）
  于「们」
  于（会「子」而「低层生成」于「上下」于「下个」于「深」于「子」）））而
  鉴「项」而
    有「项整」于「数」则
      「列」【「网页常量」于「数」】
    或有「项局」于「名」则
      「列」【「网页局部读取」于（「低层局部下标」于「上下」于「名」）】
    或有「项串」于「文」则
      「低层出错」授以（「列」于「网页指令」）
      于（『字符串字面不能作为值使用，只能作为静态串的实参：』附「文」）
    或有「项引」于「文件」于「名」则
      「低层出错」授以（「列」于「网页指令」）
      于（『顶层常量引用未被代入：』附「文件」附『#』附「名」）
    或有「项局函」于「名」于「形们」于「体」于「余」则
      「低层出错」授以（「列」于「网页指令」）
      于（『局部函数未被提升：』附「名」）
    或有「项局调」于「名」于「参们」则
      「低层出错」授以（「列」于「网页指令」）
      于（『局部函数调用未被提升：』附「名」）
    或有「项调」于「名」于「参们」则
      「串联」授以「网页指令」
      于（「列」【「生成们」于「参们」，「列」【「网页调用」于（「低层函数下标」于「上下」于「名」）】】）
    或有「项外」于「名」于「参们」则
      「低层生成外」
        于（会「子」而「低层生成」于「上下」于「下个」于「深」于「子」）
        于「上下」于「名」于「参们」
    或有「项若」于「条」于「真」于「假」则
      「串联」授以「网页指令」
      于（「列」【
        「低层生成」于「上下」于「下个」于「深」于「条」，
        「列」【「网页条件」于「一」】，
        「低层生成」于「上下」于「下个」于（「加」于「深」于「一」）于「真」，
        「列」【「网页否则」】，
        「低层生成」于「上下」于「下个」于（「加」于「深」于「一」）于「假」，
        「列」【「网页结束」】
      】）
    或有「项令」于「名」于「值」于「体」则（
      虑「值令」者
        （「低层项」也（
            鉴「值」而
              有「项外」于「外名」于（「列」【「初」】）则（
                若「串相等」于「外名」于『底层_新格』则「初」否则「值」）
              或有「余值」则「值」
          ））
      而
      若「等于」于（「低层引用数」于「名」于「体」）于「零」
      则
        「串联」授以「网页指令」于（「列」【
          「低层生成」于「上下」于「下个」于「深」于「值令」，
          「列」【「网页弃值」】，
          「低层生成」于「上下」于「下个」于「深」于「体」
        】）
      否则
        「串联」授以「网页指令」于（「列」【
          「低层生成」于「上下」于「下个」于「深」于「值令」，
          「列」【「网页局部写入」于「下个」】，
          「低层生成」
            于（「低层加局部」于「上下」于「名」于「下个」）
            于（「加」于「下个」于「一」）于「深」于「体」
        】）
    ）
    或有「项环」于「标」于「形们」于「初们」于「体」则（
      虑「分配」者
        「低层环分配」
          于「上下」
          于「下个」
          于「形们」
          于「初们」
          于（「罄」授以「整数」）
          于（「罄」授以（「整数」合「低层项」））而
      鉴「分配」而
        有「构造环分配结果」于「新上下」于「新个」于「局们」于「待赋们」则（
          虑「初令」者
            「串联」授以「网页指令」于（「态射」授以（「整数」合「低层项」）授以（「列」于「网页指令」）
            于「待赋们」
            于（会「对」而「低层生成」于「上下」于「下个」于「深」于（「对」中「一」）））
          而
          虑「赋令」者
            「串联」授以「网页指令」于（「态射」授以（「整数」合「低层项」）授以（「列」于「网页指令」）
            于（「反转」授以（「整数」合「低层项」）于「待赋们」）
            于（会「对」而「列」【「网页局部写入」于（「对」中「零」）】））
          而
          虑「环上下」者
            「低层加环」于「新上下」于「标」于「深」于「局们」
          而
          「串联」授以「网页指令」于（「列」【
            「初令」，
            「赋令」，
            「列」【「网页循环」于「一」】，
            「低层生成」
              于「环上下」于「新个」
              于（「加」于「深」于「一」）于「体」，
              「列」【「网页结束」】
          】）
        ）
    ）
    或有「项续」于「标」于「参们」则（
      鉴「低层查环表」于（「低层环表」于「上下」）于「标」而
        有「可有」于「对」则（
          虑「环深」者「对」中「零」
          而
          虑「局们」者「对」中「一」
          而
          若「不等于」
            于（「长度」授以「整数」于「局们」）
            于（「长度」授以「低层项」于「参们」）则
              「低层出错」授以（「列」于「网页指令」）
              于（『续的实参个数与环形参个数不符：』附「标」）
          否则
            虑「配对」者
              「态射」授以「整数」授以（「整数」合「低层项」）
              于（「整数范围」于「零」于（「长度」授以「整数」于「局们」））
              于（会「序」而（（「第N个」授以「整数」于「序」于「局们」）与（「第N个」授以「低层项」于「序」于「参们」）
              ））
            而
            虑「需赋」者
              「滤」授以（「整数」合「低层项」）
              于（会「对」而鉴「对」中「一」而
                有「项局」于「他」则
                  「非」于（「等于」于（「低层局部下标」于「上下」于「他」）于（「对」中「零」））
                或有「余项」则「阳」）于「配对」
            而
            「串联」授以「网页指令」于（「列」【
              「串联」授以「网页指令」于（「态射」授以（「整数」合「低层项」）授以（「列」于「网页指令」）
              于「需赋」
              于（会「对」而「低层生成」于「上下」于「下个」于「深」于（「对」中「一」））），
              「串联」授以「网页指令」于（「态射」授以（「整数」合「低层项」）授以（「列」于「网页指令」）
              于（「反转」授以（「整数」合「低层项」）于「需赋」）
              于（会「对」而「列」【「网页局部写入」于（「对」中「零」）】）），
              「列」【「网页跳转」于（「减」于（「减」于「深」于「一」）于「环深」）】
            】）
        ）
        或有「可无」则
          「低层出错」授以（「列」于「网页指令」）
          于（『续所指的环不存在：』附「标」）
    ）
    或有「项派」于「被」于「分们」于「缺」则（
      虑「数」者「长度」授以（「整数」合「低层项」）于「分们」
      而
      虑「前置暂」者
        （（「列」于「网页指令」）也（
            鉴「被」而
              有「项局」于「变」则
                「罄」授以「网页指令」
              或有「余被」则
                「串联」授以「网页指令」
                于（「列」【
                  「低层生成」于「上下」于「下个」于「深」于「被」，
                  「列」【「网页局部写入」于「下个」】】）
          ）
        ）
      而
      虑「暂」者
        （「整数」也（鉴「被」而
        有「项局」于「变」则「低层局部下标」于「上下」于「变」
        或有「余被」则「下个」））
      而
      虑「体下个」者
        （「整数」也（鉴「被」而
        有「项局」于「变」则「下个」
        或有「余被」则「加」于「下个」于「一」））
      而
      虑「对们」者
        「低层排序」于（「态射」授以「整数」授以（「整数」合「整数」）
        于（「整数范围」于「零」于「数」）
        于（会「序」而（（（「第N个」授以（「整数」合「低层项」）于「序」于「分们」）中「零」）与「序」）））
      而
      虑「树」者「低层决策树」于「暂」于「对们」于「数」于「零」
      而
      虑「体们」者
        「串联」授以「网页指令」于（「态射」授以「整数」授以（「列」于「网页指令」）
        于（「整数范围」于「零」于（「加」于「数」于「一」））
        于（会「序」
          而
  虑「本深」者
    「减」于（「加」于（「加」于「深」于「数」）于「一」）于「序」而
    虑「体项」者
      （「低层项」也（
          若「小于」于「序」于「数」则（（「第N个」授以（「整数」合「低层项」）于「序」于「分们」）中「一」）否则「缺」
        ））
    而
    「串联」授以「网页指令」于（「列」【
      「列」【「网页结束」】，
      「低层生成」于「上下」于「体下个」于「本深」于「体项」，
      若「小于」于「序」于「数」则「列」【「网页跳转」于（「减」于「数」于「序」）】否则「罄」授以「网页指令」
    】）））
      而
      「串联」授以「网页指令」于（「列」【
        「前置暂」，
        「列」【「网页块」于「一」】，
        「串联」授以「网页指令」于（「态射」授以「整数」授以（「列」于「网页指令」）
        于（「整数范围」于「零」于（「加」于「数」于「一」））
        于（会「序」而「列」【「网页块」于「零」】）），
        「树」，
        「体们」，
        「列」【「网页结束」】
      】）
    ）
也。
